Add linter jsonlint for json

README.md

@@ -33,6 +33,7 @@ name. That seems to be the fairest way to arrange this table.
 | Fortran | [gcc](https://gcc.gnu.org/) |
 | Haskell | [ghc](https://www.haskell.org/ghc/)^ |
 | JavaScript | [eslint](http://eslint.org/), [jscs](http://jscs.info/), [jshint](http://jshint.com/) |
+| Json | [jsonlint](http://zaa.ch/jsonlint/) |
 | Python | [flake8](http://flake8.pycqa.org/en/latest/) |
 | Ruby   | [rubocop](https://github.com/bbatsov/rubocop) |
 | Vim | [vint](https://github.com/Kuniwak/vint)^ |

ale_linters/json/jsonlint.vim

@@ -0,0 +1,44 @@
+" Author: KabbAmine <amine.kabb@gmail.com>
+
+if exists('g:loaded_ale_linters_json_jsonlint')
+    finish
+endif
+
+let g:loaded_ale_linters_json_jsonlint = 1
+
+function! ale_linters#json#jsonlint#Handle(buffer, lines)
+    " Matches patterns like the following:
+    " line 2, col 15, found: 'STRING' - expected: 'EOF', '}', ',', ']'.
+
+    let pattern = 'line \(\d\+\), col \(\d*\), \(.\+\)'
+    let output = []
+
+    for line in a:lines
+        let match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        " vcol is needed to indicate that the column is a character
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': match[1] + 0,
+        \   'vcol': 0,
+        \   'col': match[2] + 0,
+        \   'text': match[3],
+        \   'type': 'E',
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('json', {
+\   'name': 'jsonlint',
+\   'executable': 'jsonlint',
+\   'output_stream': 'stderr',
+\   'command': 'jsonlint --compact -',
+\   'callback': 'ale_linters#json#jsonlint#Handle',
+\})