diff --git a/autoload/ale.vim b/autoload/ale.vim
index 1664e710..ee1a0d54 100644
--- a/autoload/ale.vim
+++ b/autoload/ale.vim
@@ -5,11 +5,18 @@
 " Strings used for severity in the echoed message
 let g:ale_echo_msg_error_str = get(g:, 'ale_echo_msg_error_str', 'Error')
 let g:ale_echo_msg_info_str = get(g:, 'ale_echo_msg_info_str', 'Info')
+let g:ale_echo_msg_log_str = get(g:, 'ale_echo_msg_log_str', 'Log')
 let g:ale_echo_msg_warning_str = get(g:, 'ale_echo_msg_warning_str', 'Warning')
 " Ignoring linters, for disabling some, or ignoring LSP diagnostics.
 let g:ale_linters_ignore = get(g:, 'ale_linters_ignore', {})
 let g:ale_disable_lsp = get(g:, 'ale_disable_lsp', 0)
 
+" LSP window/showMessage format
+let g:ale_lsp_show_message_format = get(g:, 'ale_lsp_show_message_format', '%severity%:%linter%: %s')
+" Valid values mimic LSP definitions (error, warning and information; log is
+" never shown)
+let g:ale_lsp_show_message_severity = get(g:, 'ale_lsp_show_message_severity', 'error')
+
 let s:lint_timer = -1
 let s:getcmdwintype_exists = exists('*getcmdwintype')
 
diff --git a/autoload/ale/lsp_linter.vim b/autoload/ale/lsp_linter.vim
index 190a16b4..e4148ceb 100644
--- a/autoload/ale/lsp_linter.vim
+++ b/autoload/ale/lsp_linter.vim
@@ -130,6 +130,12 @@ function! ale#lsp_linter#HandleLSPResponse(conn_id, response) abort
         call s:HandleLSPErrorMessage(l:linter_name, a:response)
     elseif l:method is# 'textDocument/publishDiagnostics'
         call s:HandleLSPDiagnostics(a:conn_id, a:response)
+    elseif l:method is# 'window/showMessage'
+        call ale#lsp_window#HandleShowMessage(
+        \   s:lsp_linter_map[a:conn_id],
+        \   g:ale_lsp_show_message_format,
+        \   a:response.params
+        \)
     elseif get(a:response, 'type', '') is# 'event'
     \&& get(a:response, 'event', '') is# 'semanticDiag'
         call s:HandleTSServerDiagnostics(a:response, 'semantic')
diff --git a/autoload/ale/lsp_window.vim b/autoload/ale/lsp_window.vim
new file mode 100644
index 00000000..15cd0a1e
--- /dev/null
+++ b/autoload/ale/lsp_window.vim
@@ -0,0 +1,58 @@
+" Author: suoto <andre820@gmail.com>
+" Description: Handling of window/* LSP methods, although right now only
+" handles window/showMessage
+
+" Constants for message type codes
+let s:LSP_MESSAGE_TYPE_DISABLED = 0
+let s:LSP_MESSAGE_TYPE_ERROR = 1
+let s:LSP_MESSAGE_TYPE_WARNING = 2
+let s:LSP_MESSAGE_TYPE_INFORMATION = 3
+let s:LSP_MESSAGE_TYPE_LOG = 4
+
+" Translate strings from the user config to a number so we can check
+" severities
+let s:CFG_TO_LSP_SEVERITY = {
+\   'disabled': s:LSP_MESSAGE_TYPE_DISABLED,
+\   'error': s:LSP_MESSAGE_TYPE_ERROR,
+\   'warning': s:LSP_MESSAGE_TYPE_WARNING,
+\   'information': s:LSP_MESSAGE_TYPE_INFORMATION,
+\   'info': s:LSP_MESSAGE_TYPE_INFORMATION,
+\   'log': s:LSP_MESSAGE_TYPE_LOG
+\}
+
+" Handle window/showMessage response.
+" - details: dict containing linter name and format (g:ale_lsp_show_message_format)
+" - params: dict with the params for the call in the form of {type: number, message: string}
+function! ale#lsp_window#HandleShowMessage(linter_name, format, params) abort
+    let l:message = a:params.message
+    let l:type = a:params.type
+
+    " Get the configured severity level threshold and check if the message
+    " should be displayed or not
+    let l:configured_severity = tolower(get(g:, 'ale_lsp_show_message_severity', 'error'))
+    " If the user has confgured with a value we can't find on the conversion
+    " dict, fall back to warning
+    let l:cfg_severity_threshold = get(s:CFG_TO_LSP_SEVERITY, l:configured_severity, s:LSP_MESSAGE_TYPE_WARNING)
+
+    if l:type > l:cfg_severity_threshold
+        return
+    endif
+
+    " Severity will depend on the message type
+    if l:type is# s:LSP_MESSAGE_TYPE_ERROR
+        let l:severity = g:ale_echo_msg_error_str
+    elseif l:type is# s:LSP_MESSAGE_TYPE_INFORMATION
+        let l:severity = g:ale_echo_msg_info_str
+    elseif l:type is# s:LSP_MESSAGE_TYPE_LOG
+        let l:severity = g:ale_echo_msg_log_str
+    else
+        " Default to warning just in case
+        let l:severity = g:ale_echo_msg_warning_str
+    endif
+
+    let l:string = substitute(a:format, '\V%severity%', l:severity, 'g')
+    let l:string = substitute(l:string, '\V%linter%', a:linter_name, 'g')
+    let l:string = substitute(l:string, '\V%s\>', l:message, 'g')
+
+    call ale#util#ShowMessage(l:string)
+endfunction
diff --git a/doc/ale.txt b/doc/ale.txt
index b142e956..177b67df 100644
--- a/doc/ale.txt
+++ b/doc/ale.txt
@@ -801,6 +801,15 @@ g:ale_echo_msg_info_str                               *g:ale_echo_msg_info_str*
   The string used for `%severity%` for info. See |g:ale_echo_msg_format|
 
 
+g:ale_echo_msg_log_str                                 *g:ale_echo_msg_log_str*
+
+  Type: |String|
+  Default: `'Log'`
+
+  The string used for `%severity%` for log, used only for handling LSP show
+  message requests. See |g:ale_lsp_show_message_format|
+
+
 g:ale_echo_msg_warning_str                         *g:ale_echo_msg_warning_str*
 
   Type: |String|
@@ -1251,6 +1260,46 @@ b:ale_loclist_msg_format                             *b:ale_loclist_msg_format*
 
   The strings for configuring `%severity%` are also used for this option.
 
+
+g:ale_lsp_show_message_format                           *g:ale_lsp_show_message_format*
+
+  Type: |String|
+  Default: `'%severity%:%linter%: %s'`
+
+  This variable defines the format that messages received from an LSP will
+  have when echoed. The following sequences of characters will be replaced.
+
+    `%s`           - replaced with the message text
+    `%linter%`     - replaced with the name of the linter
+    `%severity%`   - replaced with the severity of the message
+
+  The strings for `%severity%` levels "error", "info" and "warning" are shared
+  with |g:ale_echo_msg_format|. Severity "log" is unique to
+  |g:ale_lsp_show_message_format| and it can be configured via
+
+    |g:ale_echo_msg_log_str|     - Defaults to `'Log'`
+
+  Please note that |g:ale_lsp_show_message_format| *can not* be configured
+  separately for each buffer like |g:ale_echo_msg_format| can.
+
+
+g:ale_lsp_show_message_severity                         *g:ale_lsp_show_message_severity*
+
+  Type: |String|
+  Default: `'error'`
+
+  This variable defines the minimum severity level an LSP message needs to be
+  displayed. Messages below this level are discarded; please note that
+  messages with `Log` severity level are always discarded.
+
+  Possible values follow the LSP spec `MessageType` definition:
+
+  `'error'`       - Displays only errors.
+  `'warning'`     - Displays errors and warnings.
+  `'information'` - Displays errors, warnings and infos
+  `'log'`         - Same as `'information'`
+
+
 g:ale_lsp_root                                                 *g:ale_lsp_root*
 b:ale_lsp_root                                                 *b:ale_lsp_root*
 
diff --git a/test/lsp/test_handling_window_requests.vader b/test/lsp/test_handling_window_requests.vader
new file mode 100644
index 00000000..551d5975
--- /dev/null
+++ b/test/lsp/test_handling_window_requests.vader
@@ -0,0 +1,94 @@
+Before:
+  let g:expr_list = []
+  let g:linter_name = 'some_linter'
+  let g:format = '%severity%:%linter%: %s'
+  " Get the default value to restore it
+  let g:default_severity = g:ale_lsp_show_message_severity
+  let g:ale_lsp_show_message_severity = 'information'
+
+  function! ale#util#ShowMessage(expr) abort
+    call add(g:expr_list, a:expr)
+  endfunction
+
+After:
+  unlet! g:expr_list
+  unlet! g:linter_name
+  unlet! g:format
+  let g:ale_lsp_show_message_severity = g:default_severity
+  unlet! g:default_severity
+
+Execute(ale#lsp_window#HandleShowMessage() should only show errors when severity is set to "error"):
+  let g:ale_lsp_show_message_severity = 'error'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual ['Error:some_linter: an error'], g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should only show errors and warnings when severity is set to "warning"):
+  let g:ale_lsp_show_message_severity = 'warning'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual ['Error:some_linter: an error', 'Warning:some_linter: a warning'], g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should only show errors, warnings and infos when severity is set to "information"):
+  let g:ale_lsp_show_message_severity = 'information'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual [
+  \ 'Error:some_linter: an error',
+  \ 'Warning:some_linter: a warning',
+  \ 'Info:some_linter: an info'],
+  \ g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should only show errors, warnings and infos when severity is set to "info"):
+  let g:ale_lsp_show_message_severity = 'info'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual [
+  \ 'Error:some_linter: an error',
+  \ 'Warning:some_linter: a warning',
+  \ 'Info:some_linter: an info'],
+  \ g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should show all messages is severity is set to "log"):
+  let g:ale_lsp_show_message_severity = 'log'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual [
+  \ 'Error:some_linter: an error',
+  \ 'Warning:some_linter: a warning',
+  \ 'Info:some_linter: an info',
+  \ 'Log:some_linter: a log'],
+  \ g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should not show anything if severity is configured as disabled):
+  let g:ale_lsp_show_message_severity = 'disabled'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual [], g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should use "warning" when severity is set to an invalid value):
+  let g:ale_lsp_show_message_severity = 'foo'
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':1,'message':'an error'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':2,'message':'a warning'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':'an info'})
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':4,'message':'a log'})
+  AssertEqual [
+  \ 'Error:some_linter: an error',
+  \ 'Warning:some_linter: a warning'],
+  \ g:expr_list
+
+Execute(ale#lsp_window#HandleShowMessage() should escape quotes on messages):
+  call ale#lsp_window#HandleShowMessage(g:linter_name, g:format, {'type':3,'message':"this is an 'info'"})
+  AssertEqual ['Info:some_linter: this is an ''info'''], g:expr_list