7f0ce89d2b
* First pass at optimizing ale to autoload First off, the structure/function names should be revised a bit, but I will wait for @w0rp's input before unifying the naming style. Second off, the docs probably need some more work, I just did some simple find-and-replace work. With that said, this pull brings major performance gains for ale. On my slowest system, fully loading ale and all its code takes around 150ms. I have moved all of ale's autoload-able code to autoload/, and in addition, implemented lazy-loading of linters. This brings load time on that same system down to 5ms. The only downside of lazy loading is that `g:ale_linters` cannot be changed at runtime; however, it also speeds up performance at runtime by simplfying the logic greatly. Please let me know what you think! Closes #59 * Address Travis/Vint errors For some reason, ale isn't running vint for me... * Incorporate feedback, make fixes Lazy-loading logic is much improved. * Add header comments; remove incorrect workaround * Remove unneeded plugin guards * Fix lazy-loading linter logic Set the wrong variable.... * Fix capitialization
48 lines
1.2 KiB
VimL
48 lines
1.2 KiB
VimL
" Author: KabbAmine <amine.kabb@gmail.com>
|
|
" Description: HTMLHint for checking html files
|
|
|
|
if exists('g:loaded_ale_linters_html_htmlhint')
|
|
finish
|
|
endif
|
|
|
|
let g:loaded_ale_linters_html_htmlhint = 1
|
|
|
|
function! ale_linters#html#htmlhint#Handle(buffer, lines) abort
|
|
" Matches patterns lines like the following:
|
|
"stdin:7:10: <title></title> must not be empty. [error/title-require]
|
|
|
|
let pattern = '^stdin:\(\d\+\):\(\d\+\): \(.\+\)$'
|
|
let output = []
|
|
|
|
for line in a:lines
|
|
let match = matchlist(line, pattern)
|
|
|
|
if len(match) == 0
|
|
continue
|
|
endif
|
|
|
|
let line = match[1] + 0
|
|
let col = match[2] + 0
|
|
let text = match[3]
|
|
|
|
" vcol is Needed to indicate that the column is a character.
|
|
call add(output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': line,
|
|
\ 'vcol': 0,
|
|
\ 'col': col,
|
|
\ 'text': text,
|
|
\ 'type': 'E',
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return output
|
|
endfunction
|
|
|
|
call ale#linter#Define('html', {
|
|
\ 'name': 'htmlhint',
|
|
\ 'executable': 'htmlhint',
|
|
\ 'command': 'htmlhint --format=unix stdin',
|
|
\ 'callback': 'ale_linters#html#htmlhint#Handle',
|
|
\})
|