4b0f3257dd
* Remove 'col' from linters where it is hardcoded to 1 When 'col' is 1, the first column will get highlighted for no reason. It should be 0 (which is the default). In the scalac linter there was also a check about the outcome of `stridx`. It would set l:col to 0 if it was -1, and then it uses `'col': l:col + 1` to convert the outcome of `stridx` to the actual column number. This will make 'col' equals 1 when there is no match. We can remove the check because `-1 + 1 = 0`. * Remove outdated comments about vcol vcol was added as a default, and the loclists that follow these comments do not contain 'vcol' anymore
55 lines
1.7 KiB
VimL
55 lines
1.7 KiB
VimL
" Author: KabbAmine <amine.kabb@gmail.com>
|
|
|
|
let g:ale_yaml_yamllint_executable =
|
|
\ get(g:, 'ale_yaml_yamllint_executable', 'yamllint')
|
|
|
|
let g:ale_yaml_yamllint_options =
|
|
\ get(g:, 'ale_yaml_yamllint_options', '')
|
|
|
|
function! ale_linters#yaml#yamllint#GetExecutable(buffer) abort
|
|
return g:ale_yaml_yamllint_executable
|
|
endfunction
|
|
|
|
function! ale_linters#yaml#yamllint#GetCommand(buffer) abort
|
|
return ale_linters#yaml#yamllint#GetExecutable(a:buffer)
|
|
\ . ' ' . g:ale_yaml_yamllint_options
|
|
\ . ' -f parsable %t'
|
|
endfunction
|
|
|
|
function! ale_linters#yaml#yamllint#Handle(buffer, lines) abort
|
|
" Matches patterns line the following:
|
|
" something.yaml:1:1: [warning] missing document start "---" (document-start)
|
|
" something.yml:2:1: [error] syntax error: expected the node content, but found '<stream end>'
|
|
let l:pattern = '^.*:\(\d\+\):\(\d\+\): \[\(error\|warning\)\] \(.\+\)$'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:line = l:match[1] + 0
|
|
let l:col = l:match[2] + 0
|
|
let l:type = l:match[3]
|
|
let l:text = l:match[4]
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:line,
|
|
\ 'col': l:col,
|
|
\ 'text': l:text,
|
|
\ 'type': l:type ==# 'error' ? 'E' : 'W',
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('yaml', {
|
|
\ 'name': 'yamllint',
|
|
\ 'executable_callback': 'ale_linters#yaml#yamllint#GetExecutable',
|
|
\ 'command_callback': 'ale_linters#yaml#yamllint#GetCommand',
|
|
\ 'callback': 'ale_linters#yaml#yamllint#Handle',
|
|
\})
|