7f0ce89d2b
* First pass at optimizing ale to autoload First off, the structure/function names should be revised a bit, but I will wait for @w0rp's input before unifying the naming style. Second off, the docs probably need some more work, I just did some simple find-and-replace work. With that said, this pull brings major performance gains for ale. On my slowest system, fully loading ale and all its code takes around 150ms. I have moved all of ale's autoload-able code to autoload/, and in addition, implemented lazy-loading of linters. This brings load time on that same system down to 5ms. The only downside of lazy loading is that `g:ale_linters` cannot be changed at runtime; however, it also speeds up performance at runtime by simplfying the logic greatly. Please let me know what you think! Closes #59 * Address Travis/Vint errors For some reason, ale isn't running vint for me... * Incorporate feedback, make fixes Lazy-loading logic is much improved. * Add header comments; remove incorrect workaround * Remove unneeded plugin guards * Fix lazy-loading linter logic Set the wrong variable.... * Fix capitialization
55 lines
1.4 KiB
VimL
55 lines
1.4 KiB
VimL
" Author: w0rp <devw0rp@gmail.com>
|
|
" Description: flake8 for python files
|
|
|
|
if exists('g:loaded_ale_linters_python_flake8')
|
|
finish
|
|
endif
|
|
|
|
let g:loaded_ale_linters_python_flake8 = 1
|
|
|
|
function! ale_linters#python#flake8#Handle(buffer, lines)
|
|
" Matches patterns line the following:
|
|
"
|
|
" stdin:6:6: E111 indentation is not a multiple of four
|
|
let pattern = '^stdin:\(\d\+\):\(\d\+\): \([^ ]\+\) \(.\+\)$'
|
|
let output = []
|
|
|
|
for line in a:lines
|
|
let l:match = matchlist(line, pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let line = l:match[1] + 0
|
|
let column = l:match[2] + 0
|
|
let code = l:match[3]
|
|
let text = code . ': ' . l:match[4]
|
|
let type = code[0] ==# 'E' ? 'E' : 'W'
|
|
|
|
if code ==# 'W291' && !g:ale_warn_about_trailing_whitespace
|
|
" Skip warnings for trailing whitespace if the option is off.
|
|
continue
|
|
endif
|
|
|
|
" vcol is Needed to indicate that the column is a character.
|
|
call add(output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': line,
|
|
\ 'vcol': 0,
|
|
\ 'col': column,
|
|
\ 'text': text,
|
|
\ 'type': type,
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return output
|
|
endfunction
|
|
|
|
call ale#linter#Define('python', {
|
|
\ 'name': 'flake8',
|
|
\ 'executable': 'flake8',
|
|
\ 'command': 'flake8 -',
|
|
\ 'callback': 'ale_linters#python#flake8#Handle',
|
|
\})
|